problem with button array

[threat45]

Hello Community ( You last visited: 05-10-2005 at 11:08 AM !)

long time no see

I'm loading some xml to populate urls for buttons

var home:MovieClip = this;

xmlData = new XML();
xmlData.ignoreWhite = true;
xmlData.onLoad = loadXML;
xmlData.load("template.xml");

function loadXML(loaded) {
    if (loaded) {
        xmlNode = this.firstChild;

        weburl = [];
        total = xmlNode.childNodes.length;
        for (i=0; i<total; i++) {
            weburl[i] = xmlNode.childNodes[i].childNodes[0].firstChild.nodeValue;
            
            var mc:MovieClip = home["_icon" + i];
            var url_txt:String = weburl[i];
            trace(url_txt);
            

            mc.onRollOver = function() {
                //getURL(url_txt, "_BLANK");
                trace(url_txt);
            }
        }
    } else {
        content = "file not loaded.";
    }
}

when I run this code i get back the list of urls, but when I rollover the button it only gives me back the last url for all the buttons.

Can someone point me in the right direction? Any help is much appreciated.

thanks for looking!

[mgminthu]

Please take a look at below 2 flash source files. You will get an idea.

Vertical Menu
Horizontal Menu

[silentweed]

When u press the button 'i' is simple the last value that the loop incrementer 'i' had .. assign an id to the movieclips before hand:

function loadXML(loaded) {
    if (loaded) {
        xmlNode = this.firstChild;

        weburl = [];
        total = xmlNode.childNodes.length;
        for (i=0; i<total; i++) {
            weburl[i] = xmlNode.childNodes[i].childNodes[0].firstChild.nodeValue;
            
            var mc:MovieClip = home["_icon" + i];
	    mc.id = i;
          
            mc.onRollOver = function() {
                //getURL(url_txt, "_BLANK");
                trace(weburl[this.id]);
            }
        }
    } else {
        content = "file not loaded.";
    }
}