A Flash Developer Resource Site

Results 1 to 2 of 2

Thread: XML Gallery / 12 images per page with nav buttons?

  1. #1
    Junior Member
    Join Date
    Mar 2008
    Posts
    19

    XML Gallery / 12 images per page with nav buttons?

    I have an image gallery that loads images from an XML file. This is fine but if u upload more than 16 images the gallery has no room to display the 16th image. How would I go about adding a next and previous button that will only show 15 images per page in the gallery?

    Here is my gallery code so far:

    Code:
    // Import the transitions classes so you can add a fading effect when the images load to the Stage.
    import mx.transitions.*;
    
    // Set the starting X and Y positions for the gallery images.
    _global.thisX = 40;
    _global.thisY = 40;
    
    /* Set static values for the Stage's width and height. 
       Using Stage. */
    _global.stageWidth = 600;
    _global.stageHeight = 400;
    
    // Create and configure the XML instance which is used to load the list of gallery images
    var gallery_xml:XML = new XML();
    gallery_xml.ignoreWhite = true;
    gallery_xml.onLoad = function(success:Boolean) {
    	try {
    		/* if you are able to successfully load and parse the gallery from a remote XML file, 
    		   parse out the image names and add them to an array. */
    		if (success) {
    			var images:Array = this.firstChild.childNodes;
    			var gallery_array:Array = new Array();
    			for (var i = 0; i<images.length; i++) {
    				gallery_array.push({src:images[i].firstChild.nodeValue});
    			}
    			/* call the displayGallery function which handles loading in each 
    			   of the gallery images and placing them on the Stage. */
    			displayGallery(gallery_array);
    		} else {
    			throw new Error("Unable to parse XML");
    		}
    	} catch (e_err:Error) {
    		trace(e_err.message);
    	} finally {
    		delete this;
    	}
    };
    
    // load the gallery.xml file from the current directory.
    gallery_xml.load("images.xml");
    
    /* create a function which loops through the images in an array,
       and creates new movie clips on the Stage. */
    function displayGallery(gallery_array:Array) {
    	var galleryLength:Number = gallery_array.length;
    	// loop through each of the images in the gallery_array.
    	for (var i = 0; i<galleryLength; i++) {
    		/* create a movie clip instance which holds the image.variable, 
    		   thisMC, is an alias to the movie clip instance. */
    		var thisMC:MovieClip = this.createEmptyMovieClip("image"+i+"_mc", i);
    		
    		/* load the current image source into the new movie clip instance, 
    		   using the MovieClipLoader class. */
    		mcLoader_mcl.loadClip(gallery_array[i].src, thisMC);
    		
    		// attach the preloader symbol from the Library onto the Stage.
    		preloaderMC = this.attachMovie("preloader_mc", "preloader"+i+"_mc", 5000+i);
    		
    		/* set the preloader's bar_mc's _xscale property to 0% 
    		   and set a default value in the progress bars text field. */
    		preloaderMC.bar_mc._xscale = 0;
    		preloaderMC.progress_txt.text = "0%";
    		
    		// set the _x and _y coordinates of the new movie clip.
    		thisMC._x = _global.thisX;
    		thisMC._y = _global.thisY;
    		
    		// set the position of the image preloader.
    		preloaderMC._x = _global.thisX;
    		preloaderMC._y = _global.thisY+20;
    		
    		// if you've displayed 5 columns of images, start a new row.
    		if ((i+1)%4 == 0) {
    			// reset the X and Y positions
    			_global.thisX = 30;
    			_global.thisY += 80;
    		} else {
    			_global.thisX += 90+30;
    		}
    	}
    }
    
    // define the MovieClipLoader instance and MovieClipLoader listener Object.
    var mcLoader_mcl:MovieClipLoader = new MovieClipLoader();
    var mclListener:Object = new Object();
    mclListener.onLoadStart = function() {
    };
    
    // while the content is preloading, modify the width of the progress bar.
    mclListener.onLoadProgress = function(target_mc, loadedBytes, totalBytes) {
    	var pctLoaded:Number = Math.round(loadedBytes/totalBytes*100);
    	// create a shortcut for the path to the preloader movie clip.
    	var preloaderMC = target_mc._parent["preloader"+target_mc.getDepth()+"_mc"];
    	preloaderMC.bar_mc._xscale = pctLoaded;
    	preloaderMC.progress_txt.text = pctLoaded+"%";
    };
    
    // when the onLoadInit event is thrown, you're free to position the instances 
    mclListener.onLoadInit = function(evt:MovieClip) {
    	evt._parent["preloader"+evt.getDepth()+"_mc"].removeMovieClip();
    	/* set local variables for the target movie clip's width and height,
    	   and the desired settings for the image stroke and border. */
    	var thisWidth:Number = evt._width;
    	var thisHeight:Number = evt._height;
    	var borderWidth:Number = 2;
    	var marginWidth:Number = 8;
    	evt.scale = 20;
    	// draw a white rectangle with a black stroke around the images.
    	evt.lineStyle(borderWidth, 0x000000, 100);
    	evt.beginFill(0xFFFFFF, 100);
    	evt.moveTo(-borderWidth-marginWidth, -borderWidth-marginWidth);
    	evt.lineTo(thisWidth+borderWidth+marginWidth, -borderWidth-marginWidth);
    	evt.lineTo(thisWidth+borderWidth+marginWidth, thisHeight+borderWidth+marginWidth);
    	evt.lineTo(-borderWidth-marginWidth, thisHeight+borderWidth+marginWidth);
    	evt.lineTo(-borderWidth-marginWidth, -borderWidth-marginWidth);
    	evt.endFill();
    	
    	/* scale the target movie clip so it appears as a thumbnail. */
    	evt._xscale = evt.scale;
    	evt._yscale = evt.scale;
    	// rotate the current image (and borders) anywyhere from -5 degrees to +5 degrees.
    	evt._rotation = Math.round(Math.random()*-10)+5;
    	/* when the target_mc movie clip instance is pressed, begin to drag the current movie clip 
    	   and set some temporary variables so once you are finished rescaling and positioning 
    	   the full image, you can return the instance to its original position. */
    	evt.onPress = function() {
    		// start dragging the current clip.
    		this.startDrag();
    		/* set the _xscale and _yscale properties back to 100% so the image appears full sized. 
    		   You're also storing the original X and Y coordinates so you can return the image where you found it. */
    		this._xscale = 100;
    		this._yscale = 100;
    		this.origX = this._x;
    		this.origY = this._y;
    		// find the depth of the current movie clip, and store it within the movie clip.
    		this.origDepth = this.getDepth();
    		/* swap the depth of the current movie clip, with the next highest movie clip of the _parent. 
    		   Effectively this makes the current movie clip the top of the "stack". */
    		this.swapDepths(this._parent.getNextHighestDepth());
    		// try and center the current movie clip on the Stage.
    		this._x = (_global.stageWidth-evt._width+30)/2;
    		this._y = (_global.stageHeight-evt._height+30)/2;
    		// apply a transition to the movie clip which makes the movie clip flicker for a split second.
    		mx.transitions.TransitionManager.start(this, {type:mx.transitions.Photo, direction:0, duration:1, easing:mx.transitions.easing.Strong.easeOut, param1:empty, param2:empty});
    	};
    	/* when the movie clip instance is released, stop dragging the movie clip. 
    	   Reset the _xscale and _yscale properties as well as the _x and _y coordinates. */
    	evt.onRelease = function() {
    		this.stopDrag();
    		this._xscale = this.scale;
    		this._yscale = this.scale;
    		this._x = this.origX;
    		this._y = this.origY;
    	};
    	// if the mouse cursor was released outside of the movie clip, call the onRelease handler.
    	evt.onReleaseOutside = evt.onRelease;
    };
    mcLoader_mcl.addListener(mclListener);
    Any help would be great

  2. #2
    Member
    Join Date
    Aug 2004
    Location
    UK
    Posts
    88
    how about something like this:

    Code:
    _root.startPoint = 0
    
    
    function displayGallery(gallery_array:Array) {
    	var galleryLength:Number = gallery_array.length;
    	// loop through each of the images in the gallery_array.
    	
    	for (var i = _root.startPoint; i<galleryLength; i++) {
    		/* create a movie clip instance which holds the image.variable, 
    		   thisMC, is an alias to the movie clip instance. */
    		
    		var thisMC:MovieClip = this.createEmptyMovieClip("image"+i+"_mc", i);
    		
    		/* load the current image source into the new movie clip instance, 
    		   using the MovieClipLoader class. */
    		
    		mcLoader_mcl.loadClip(gallery_array[i].src, thisMC);
    		
    		// attach the preloader symbol from the Library onto the Stage.
    		
    		preloaderMC = this.attachMovie("preloader_mc", "preloader"+i+"_mc", 5000+i);
    		
    		/* set the preloader's bar_mc's _xscale property to 0% 
    		   and set a default value in the progress bars text field. */
    		
    		preloaderMC.bar_mc._xscale = 0;
    		preloaderMC.progress_txt.text = "0%";
    		
    		// set the _x and _y coordinates of the new movie clip.
    		
    		thisMC._x = _global.thisX;
    		thisMC._y = _global.thisY;
    		
    		// set the position of the image preloader.
    		
    		preloaderMC._x = _global.thisX;
    		preloaderMC._y = _global.thisY+20;
    		
    		// if you've displayed 5 columns of images, start a new row.
    		if ((i+1)%4 == 0) {
    			// reset the X and Y positions
    			_global.thisX = 30;
    			_global.thisY += 80;
    		} else {
    			_global.thisX += 90+30;
    		}
    	}
    }




    Code:
    _root.next_button.onPress(){
    	//you will have to test here to make sure the start point wont drop off the end.
    	_root.startPoint++;
    	_root.displayGallery();
    
    }
    
    _root.back_button.onPress(){
    	//you will have to test here to make sure the start point become < 0
    	_root.startPoint--;
    	_root.displayGallery();
    
    }
    i havent tried this...
    http://robotnic.co.uk/
    -----------------------------------------

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •  




Click Here to Expand Forum to Full Width

HTML5 Development Center