rotating a box around one of its corners

[wonebyfase]

Ok, I have a box with the registration point (little white circle) right in the middle. I would like this box to be able to rotate around any of its four corners (only around one at a time obviously, but able to rotate around any one if specified), as if the registration point was on that corner.

I figure I would have to get the co-ordinates of that corner, then move and rotate the box by some value to keep the corner in the same position? If that's right, or not, then question is how?

Hope you understand what I'm getting at here..

Thanks

[lordofduct]

use the matrix

of course you need to know the position of the corner... so find that with respect to the DisplayObject's coordinate space.

Next it's a few steps:

transform the point to the the coordinate space the matrix exists in
subtract the point from the position of the matrix
rotate by the amount of radians you want to
add the point back onto the matrix

from the fl.motion.MatrixTransformer class:

code:

---

    /**

     * Rotates a matrix about a point defined inside the matrix's transformation space.

     * This can be used to rotate a movie clip around a transformation point inside itself. 

     *

     * @param m A Matrix instance.

     *

     * @param x The x coordinate of the point.

     *

     * @param y The y coordinate of the point.

     *

     * @param angleDegrees The angle of rotation in degrees.

     * @playerversion Flash 9.0.28.0

     * @langversion 3.0

     * @keyword Matrix, Copy Motion as ActionScript    

     * @see flash.geom.Matrix         

     */

	public static function rotateAroundInternalPoint(m:Matrix, x:Number, y:Number, angleDegrees:Number):void

	{

		var point:Point = new Point(x, y);

		point = m.transformPoint(point);

		m.tx -= point.x;

		m.ty -= point.y;

		m.rotate(angleDegrees*(Math.PI/180));

		m.tx += point.x;

		m.ty += point.y;

	}

---