[RESOLVED] Rookie bitmap help as3

[duchman]

Hello,
I have this tutorial code from AS3 Cookbook, fog like effect on Bitmap data

 import flash.display.Sprite;
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.events.Event;
    import flash.geom.Point;

 var offset:int=0;
 var bitmap:BitmapData = new BitmapData(330, 100,true,0x0);

            var image:Bitmap = new Bitmap(bitmap);
            addChild(image);
            image.x=0;
            image.y=190;
            
            addEventListener(Event.ENTER_FRAME, onEnter);
       function onEnter(event:Event):void {
            offset++;
            var point:Point = new Point(0, offset);

           
            bitmap.perlinNoise(150, 100, 5, 500, false, true,
                            8, true, [point, point]);
        }

and interested in blending it on some background.It needs to be on the bottom of movie clip, but without that bitmaps border showing around the noise effect..Threshold? Gradient?How is that achieved?
Heres fla.

[moagrius]

i'm not clear on what you want to achieve... do you want a gradient mask so it appears to gradually fade across the y axis?

[duchman]

i'm not clear on what you want to achieve... do you want a gradient mask so it appears to gradually fade across the y axis?

Thats right! I did some masking with setMask but it didnt do..Always geting that top of bitmaps border visible. I know thats either with treshold of bitmap, or some gradient masking, but just cant get that bitmap transparency right..
Anyway You got my point, so, HOW?
Thanx in advance!

[moagrius]

you create a shape, add a gradient fill, and mask the bitmap with that shape. both object need to have cacheAsBitamp set to true.

var offset:int=0;
var bitmap:BitmapData = new BitmapData(330, 100,true,0x0);

var container:Sprite = new Sprite();
container.x=0;
container.y=190;
addChild(container);

var image:Bitmap = new Bitmap(bitmap);
image.cacheAsBitmap = true;
container.addChild(image);

var matrix:Matrix = new Matrix();
matrix.createGradientBox(330, 100, Math.PI / 2);

var masker:Shape = new Shape();
masker.cacheAsBitmap = true;
masker.graphics.beginGradientFill("linear", [0, 0], [0, 1], [0, 255], matrix);
masker.graphics.drawRect(0, 0, 330, 100);
masker.graphics.endFill();
container.addChild(masker);

image.mask = masker;

addEventListener(Event.ENTER_FRAME, onEnter);
function onEnter(event:Event):void {
    offset++;
    var point:Point = new Point(0, offset);
    bitmap.perlinNoise(150, 100, 5, 500, false, true, 8, true, [point, point]);
} 

you can play with the ratios - [0, 255] - to define the position and degree of graduation

[duchman]

Oh thanx my friend, its so simple, (and thus perfect) meanwhile I actually did the code but it looks more like Ben Hur scenario..
3months of beginers as3 course is still nothing..
Yes, this is it,
THANX for Tut, and May The Code Be With You!

[moagrius]