Flash CS5:(URGENT)Drag & Drop followed by a change of frame in target moviclip (AS 2)

[WoRmTa1L]

Hi all!
I'm having a lot of projects and I really have to have this little issue surpassed as soon as possible.
Basically we are developing a mobile application for restaurants and there is a part where we drag and drop the requests of the clients in a *don't know the name in english*(the thing where you impale? your papers).
What i've done so far was to drag & drop (easy) but the issue is, I want to remove the paper when the user drops the "paper" above the *object* and then the object goes to frame 2 (which has one paper sticked in) and so on.

Thanks in Advance!

W.

[dawsonk]

spindle.gotoAndStop(1);

paper1.onPress = moveMe;
paper2.onPress = moveMe;
paper3.onPress = moveMe;

function moveMe() {
        this.startDrag();
        this.swapDepths(this._parent.getNextHighestDepth());
        this.onMouseUp = dropMe;
}
function dropMe() {
        stopDrag();
        if (eval(this._droptarget)._name == "spindle") {
                spindle.gotoAndStop(spindle._currentframe + 1);
                this.removeMovieClip();
        }
}

[WoRmTa1L]

Thanks dawsonk!
Exactly what I wanted! Just one more thing: If I miss the spindle when I drop the paper it does not goes back to the original position, what is the command that states the initial position x and y? because if I put x and y it will assume that those coordinates are the ones he is currently on and not the initial ones.

[dawsonk]

spindle.gotoAndStop(1);

paper1.onPress = moveMe;
paper2.onPress = moveMe;
paper3.onPress = moveMe;

function moveMe() {
        if (this.orgX == undefined) {
                this.orgX = this._x;
                this.orgY = this._y;
        }
        this.startDrag();
        this.swapDepths(this._parent.getNextHighestDepth());
        this.onMouseUp = dropMe;
}
function dropMe() {
        stopDrag();
        if (eval(this._droptarget)._name == "spindle") {
                spindle.gotoAndStop(spindle._currentframe + 1);
                this.removeMovieClip();
        } else {
                this._x = this.orgX;
                this._y = this.orgY;
        }
}