Flash XML Play/Pause Button?

Quote:

---

Originally Posted by dawsonk

What is the code for prevImage and nextImage functions that you are currently using?

---

dawsonk it works! :) I made the mistake of commenting out the previous prevImage and nextImage buttons after you sent me the second code. When I used the scripts together it worked wonderfully! dawsonk I appreciate your help so much! Thank you! You're the best!

This sounds like exactly what I've been looking for.

However, I'm having problems with the script... I can't get it to work. :(

I've attached what I put together after reading this thread.

Could somebody please help me? Or just post your fla/source files? I know I did something wrong, and just can't figure it out.

Thanks!

Sorry, I couldn't open your fla. (I've only got MX2004.)
But one problem is that the jpgs included are 'progressive' and flash doesn't support that.

See attached files...

(Note: The forum has a size limit for all attachments, so I'll end up removing the attached files after a while.)

HTH

Thank you so much!!

It works perfectly! I'll be modifying the buttons to match the rest of the site, but this is just what I was hoping for.

Thank you! :) :thumbsup:

Is it possible to tweak the code so that each image in the slideshow could have a link? Thanks. :)

XML file...

Code:

---

<?xml version="1.0"?>
<album>
        <pic><img>ice1.jpg</img><cap>pic01</cap><link>http://www.flashkit.com</link></pic>
        <pic><img>ice2.jpg</img><cap>pic02</cap><link>http://www.google.com</link></pic>
        <pic><img>ice3.jpg</img><cap>pic03</cap><link>http://www.flashkit.com</link></pic>
</album>

---

AS2 code on main timeline...

Code:

---

stop();
//
var myInterval = null;
var playState:Boolean = true;
var image = new Array();
var caption = new Array();
var link = new Array();
var total = 0;
var p = 0;
//
function loadXML(loaded) {
        if (loaded) {
                var xmlNode = this.firstChild;
                image = [];
                caption = [];
                link = [];
                total = xmlNode.childNodes.length;
                for (i = 0; i < total; i++) {
                        image[i] = xmlNode.childNodes[i].childNodes[0].firstChild.nodeValue;
                        caption[i] = xmlNode.childNodes[i].childNodes[1].firstChild.nodeValue;
                        link[i] = xmlNode.childNodes[i].childNodes[2].firstChild.nodeValue;
                }
                p = total;
                slideshow();
        } else {
                content = "file not loaded!";
        }
        delete xmlNode;
}
function doLoading() {
        var filesize = picture.getBytesTotal();
        var loaded = picture.getBytesLoaded();
        preloader._visible = true;
        if (loaded != filesize) {
                preloader.preload_bar._xscale = 100 * loaded / filesize;
        } else {
                preloader._visible = false;
                if (picture._alpha < 100) {
                        picture._alpha = picture._alpha + 10;
                } else {
                        picture.onPress = function() {
                                trace(link[p]);
                                //getURL(link[p], "_blank");
                        };
                        delete this.onEnterFrame;
                }
        }
}
function showPic() {
        caption_txt.text = caption[p];
        picture._alpha = 0;
        picture.loadMovie("photos/" + image[p], 1);
        this.onEnterFrame = doLoading;
}
function nextImage() {
        p = (p < total - 1) ? p + 1 : 0;
        showPic(p);
        if (playState) {
                clearInterval(myInterval);
                myInterval = setInterval(slideshow, 4000);
        }
}
function prevImage() {
        p = (p > 0) ? p - 1 : total - 1;
        showPic(p);
        if (playState) {
                clearInterval(myInterval);
                myInterval = setInterval(slideshow, 4000);
        }
}
function slideshow() {
        clearInterval(myInterval);
        p = (++p >= total) ? 0 : p;
        showPic(p);
        myInterval = setInterval(slideshow, 4000);
}
//
xmlData = new XML();
xmlData.ignoreWhite = true;
xmlData.onLoad = loadXML;
xmlData.load("photos.xml");
listen = new Object();
listen.onKeyDown = function() {
        if (Key.getCode() == 37) {
                prevImage();
        } else if (Key.getCode() == 39) {
                nextImage();
        }
};
Key.addListener(listen);
previous_btn.onRelease = function() {
        prevImage();
};
next_btn.onRelease = function() {
        nextImage();
};
btn_mc.gotoAndStop(playState);
btn_mc.onRelease = function() {
        clearInterval(myInterval);
        playState = !playState;
        this.gotoAndStop(playState);
        if (playState) {
                slideshow();
        }
};

---

You rock! :) Thanks!

I attached the working version, with the links. Sorry I can't downsave to MX2004.

One more question... Is it possible to make the back/pause-play/next menu only display when the photo is moused over? :confused:

I tried making btn and btnPP into buttons then the file didn't work. Thank goodness for the undo button!

Code:

---

function doLoading() {
        var filesize = picture.getBytesTotal();
        var loaded = picture.getBytesLoaded();
        preloader._visible = true;
        if (loaded != filesize) {
                preloader.preload_bar._xscale = 100 * loaded / filesize;
        } else {
                preloader._visible = false;
                if (picture._alpha < 100) {
                        picture._alpha = picture._alpha + 10;
                } else {
                        picture.onPress = function() {
                                trace(link[p]);
                                //getURL(link[p], "_blank");
                        };
                        picture.onEnterFrame = function() {
                                if (this.hitTest(_xmouse, _ymouse)) {
                                        previous_btn._visible = true;
                                        next_btn._visible = true;
                                        btn_mc._visible = true;
                                } else {
                                        previous_btn._visible = false;
                                        next_btn._visible = false;
                                        btn_mc._visible = false;
                                }
                        };
                        delete this.onEnterFrame;
                }
        }
}

---

:) :thumbsup: Perfect!! Thanks!

Can you post the full .fla please?

I'm after some slideshow exactly like this, just would need few adjustaments but those I can handle at my own.

All the attachments from the post were delete :(

Quote:

---

Originally Posted by Firehalk

All the attachments from the post were delete :(

---

Yes, there is a limit on the forum and I delete my older ones, when I add new ones.

But here's the files, (but they won't be here long...)

HTH

dawsonk, thanks really a lot for this.

Already did get it.

Really appreciate your help and the fast reply!

dawsonk, I was wondering... Do you think it's possible for the images to fade into each other while transitioning? (instead of to the background)

How would I do this?

Thanks!

Change the name of the instance of 'picture' on the stage to 'picA'. Make a copy of 'picA' and paste in place, name this 'picB'. Send it to the back (or move the controls and text field to a new layer above the one containing the pictures.

Code:

---

stop();
//
var myInterval = null;
var playState = true;
var image = new Array();
var caption = new Array();
var link = new Array();
var total = 0;
var p = 0;
var timeAmt = 5000;
//
function loadXML(loaded) {
        if (loaded) {
                var xmlNode = this.firstChild;
                image = [];
                caption = [];
                link = [];
                total = xmlNode.childNodes.length;
                for (i = 0; i < total; i++) {
                        image[i] = xmlNode.childNodes[i].childNodes[0].firstChild.nodeValue;
                        caption[i] = xmlNode.childNodes[i].childNodes[1].firstChild.nodeValue;
                        link[i] = xmlNode.childNodes[i].childNodes[2].firstChild.nodeValue;
                }
                p = total;
                slideshow();
        } else {
                content = "file not loaded!";
        }
        delete xmlNode;
}
function doLoading() {
        var filesize = picture.getBytesTotal();
        var loaded = picture.getBytesLoaded();
        preloader._visible = true;
        if (loaded != filesize) {
                preloader.preload_bar._xscale = 100 * loaded / filesize;
        } else {
                preloader._visible = false;
                if (picture._alpha < 100) {
                        picture._alpha += 10;
                        oldPic = (picture == picA) ? picB : picA;
                        oldPic._alpha -= 10;
                } else {
                        oldPic.unloadMovie()
                        picture.onPress = function() {
                                trace(link[p]);
                                //getURL(link[p], "_blank");
                        };
                        picture.onEnterFrame = function() {
                                if (this.hitTest(_xmouse, _ymouse)) {
                                        previous_btn._visible = true;
                                        next_btn._visible = true;
                                        btn_mc._visible = true;
                                } else {
                                        previous_btn._visible = false;
                                        next_btn._visible = false;
                                        btn_mc._visible = false;
                                }
                        };
                        delete this.onEnterFrame;
                }
        }
}
function showPic(p) {
        caption_txt.text = caption[p];
        picture = (picture == picA) ? picB : picA;
        picture._alpha = 0;
        picture.loadMovie("photos/" + image[p], 1);
        this.onEnterFrame = doLoading;
}
function nextImage() {
        p = (p < total - 1) ? p + 1 : 0;
        showPic(p);
        if (playState) {
                clearInterval(myInterval);
                myInterval = setInterval(slideshow, timeAmt);
        }
}
function prevImage() {
        p = (p > 0) ? p - 1 : total - 1;
        showPic(p);
        if (playState) {
                clearInterval(myInterval);
                myInterval = setInterval(slideshow, timeAmt);
        }
}
function slideshow() {
        clearInterval(myInterval);
        p = (++p >= total) ? 0 : p;
        showPic(p);
        myInterval = setInterval(slideshow, timeAmt);
}
//
xmlData = new XML();
xmlData.ignoreWhite = true;
xmlData.onLoad = loadXML;
xmlData.load("photos.xml");
listen = new Object();
listen.onKeyDown = function() {
        if (Key.getCode() == 37) {
                prevImage();
        } else if (Key.getCode() == 39) {
                nextImage();
        }
};
Key.addListener(listen);
previous_btn.onRelease = function() {
        prevImage();
};
next_btn.onRelease = function() {
        nextImage();
};
btn_mc.gotoAndStop(playState);
btn_mc.onRelease = function() {
        clearInterval(myInterval);
        playState = !playState;
        this.gotoAndStop(playState);
        if (playState) {
                slideshow();
        }
};

---

:domo: SWEET! Thanks.

badly worded question removed

Not sure that I understand the question... Are you looking for side scrolling gallery that is controlled by a scrollbar (and it has nothing to do with the above posts)?

No, I was looking for the original "Flash XML Play/Pause Button" slide show, but with the added feature of a scrollbar...

That was people could hit pause, play, back/next, or scroll to go through the images. Like a scrub-bar.

Does that make sense? I don't think I explained it very well. :confused:

I was thinking about using this as a slideshow on my site and wondered if it was possible to redirect to another page instead of looping. I tried changing some things on my own, but my knowledge of AS is minimal. Any help would be appreciated, thanks!

Yes.

Code:

---

stop();
//
var myInterval = null;
var playState = true;
var image = new Array();
var caption = new Array();
var link = new Array();
var total = 0;
var p = 0;
var timeAmt = 5000;
var frameNext = 6;
//
function loadXML(loaded) {
        if (loaded) {
                var xmlNode = this.firstChild;
                image = [];
                caption = [];
                link = [];
                total = xmlNode.childNodes.length;
                for (i = 0; i < total; i++) {
                        image[i] = xmlNode.childNodes[i].childNodes[0].firstChild.nodeValue;
                        caption[i] = xmlNode.childNodes[i].childNodes[1].firstChild.nodeValue;
                        link[i] = xmlNode.childNodes[i].childNodes[2].firstChild.nodeValue;
                }
                p = total;
                slideshow();
        } else {
                content = "file not loaded!";
        }
        delete xmlNode;
}
function doLoading() {
        var filesize = picture.getBytesTotal();
        var loaded = picture.getBytesLoaded();
        preloader._visible = true;
        if (loaded != filesize) {
                preloader.preload_bar._xscale = 100 * loaded / filesize;
        } else {
                preloader._visible = false;
                if (picture._alpha < 100) {
                        picture._alpha += 10;
                        oldPic = (picture == picA) ? picB : picA;
                        oldPic._alpha -= 10;
                } else {
                        oldPic.unloadMovie();
                        picture.onPress = function() {
                                trace(link[p]);
                                //getURL(link[p], "_blank");
                        };
                        picture.onEnterFrame = function() {
                                if (this.hitTest(_xmouse, _ymouse)) {
                                        previous_btn._visible = true;
                                        next_btn._visible = true;
                                        btn_mc._visible = true;
                                } else {
                                        previous_btn._visible = false;
                                        next_btn._visible = false;
                                        btn_mc._visible = false;
                                }
                        };
                        delete this.onEnterFrame;
                }
        }
}
function showPic(p) {
        caption_txt.text = caption[p];
        picture = (picture == picA) ? picB : picA;
        picture._alpha = 0;
        picture.loadMovie("photos/" + image[p], 1);
        this.onEnterFrame = doLoading;
}
function nextImage() {
        if (p == total - 1) {
                clearInterval(myInterval);
                gotoAndStop(frameNext);
        } else {
                p = (p < total - 1) ? p + 1 : 0;
                showPic(p);
                if (playState) {
                        clearInterval(myInterval);
                        myInterval = setInterval(slideshow, timeAmt);
                }
        }
}
function prevImage() {
        if (p == 0) {
                clearInterval(myInterval);
                gotoAndStop(frameNext);
        } else {
                p = (p > 0) ? p - 1 : total - 1;
                showPic(p);
                if (playState) {
                        clearInterval(myInterval);
                        myInterval = setInterval(slideshow, timeAmt);
                }
        }
}
function slideshow() {
        if (p == total - 1) {
                clearInterval(myInterval);
                gotoAndStop(frameNext);
        } else {
                clearInterval(myInterval);
                p = (++p >= total) ? 0 : p;
                showPic(p);
                myInterval = setInterval(slideshow, timeAmt);
        }
}
//
xmlData = new XML();
xmlData.ignoreWhite = true;
xmlData.onLoad = loadXML;
xmlData.load("photos.xml");
listen = new Object();
listen.onKeyDown = function() {
        if (Key.getCode() == 37) {
                prevImage();
        } else if (Key.getCode() == 39) {
                nextImage();
        }
};
Key.addListener(listen);
previous_btn.onRelease = function() {
        prevImage();
};
next_btn.onRelease = function() {
        nextImage();
};
btn_mc.gotoAndStop(playState);
btn_mc.onRelease = function() {
        clearInterval(myInterval);
        playState = !playState;
        this.gotoAndStop(playState);
        if (playState) {
                slideshow();
        }
};

---