[AS3] key/focus problem

Don't laugh, after I just said how wonderful AS3 is, I ran into a problem. It's probably easy to fix though. :)

Okay, so I have dialogs, which you close by pressing a button. So, they just say

Code:

---

this.stage.addEventListener(KeyboardEvent.KEY_DOWN, this.keyDown);

---

Which is called after they have been parented.

Code:

---

private function keyDown(e:KeyboardEvent):void {
        this.stage.removeEventListener(KeyboardEvent.KEY_DOWN, this.keyDown);
        /* etc */
}

---

But, well, sometimes the game seems to randomly stops receiving key events, especially in the IDE player with 'disable keyboard shortcuts', but I've also seen it in the web plugin. I have to click on the game again so it receives events again, so it seems to have lost focus, but there is no reason for that.

I also have a Key class somewhere which mimics Key.isDown functionality, I doubt it has any influence but it looks like this :

Code:

---

package com.crossconscious {
        import flash.display.Sprite;
        import flash.display.Stage;
        import flash.events.Event;
        import flash.events.KeyboardEvent;
       
        /**
        * ...
        * @author Sven Magnus
        */
        public class Key {
               
                public static var stage:Stage;
                private static var keys:Object = {};
               
                public static function init(stage:Stage):void {
                        Key.stage = stage;
                        Key.stage.addEventListener(KeyboardEvent.KEY_UP, Key.keyUp);
                        Key.stage.addEventListener(KeyboardEvent.KEY_DOWN, Key.keyDown);
                        Key.stage.addEventListener(Event.DEACTIVATE, Key.clearKeys);
                }
               
                private static function keyUp(e:KeyboardEvent):void {
                        if (e.keyCode in Key.keys) {
                                delete Key.keys[e.keyCode];
                        }
                }
               
                private static function keyDown(e:KeyboardEvent):void {
                        Key.keys[e.keyCode] = true;
                }
               
                public static function isDown(keyCode:int):Boolean {
                        if (Key.keys[keyCode]) return true;
                        return false;
                }
               
                private static function clearKeys(e:Event):void {
                        Key.keys = [];
                }
               
        }
       
}

---

It's probably something very obvious, but I just don't know what it is. Any ideas?

Also, just did a check, and the stage doesn't actually loose focus. I put a text field and put some text in in the Event.DEACTIVATE event of the stage, and it didn't happen, only when I actually click outside of the swf. So it still has focus, but my event callers are not called when a key gets pressed.

Okay, I found an ugly hack to fix this, and it's not hurting my game at all, so I'm satisfied, but I would still like to know why this was happening.

(my hack involves using a sprite, and setting stage.focus to that sprite each frame, and using that sprite for events, which isn't ideal but it's the only thing I tried that seems to work).

as3 is great isn't it ? ;)

I posted about the very same thing on the blog the other day, and I had to do the stage.focus=stage; thing.

Squize.

I dont see anything wrong with that code.

do you have warnings mode and strict mode on, maybe something is failing silently, like "this.stage" is undefined.

Quote:

---

Originally Posted by Squize

as3 is great isn't it ? ;)

I posted about the very same thing on the blog the other day, and I had to do the stage.focus=stage; thing.

Squize.

---

I said don't laugh :) Oh well, problems arise no matter what language you use. There's probably a perfectly reasonable explenation, otherwise it's a bug, but I really doubt that since I had this problem more than a year ago (never said anything about it because it was on a now abandoned project) and it would have been fixed if it's that easy to recreate. Do you have a link to that blog entry? Maybe I can see something that you do that I do as well to pinpoint the problem. Otherwise, the hack I use is quite simple and doesn't slow down anything. Would be nice to solve it in a clean way though.

Quote:

---

Originally Posted by mr_malee

I dont see anything wrong with that code.

do you have warnings mode and strict mode on, maybe something is failing silently, like "this.stage" is undefined.

---

Nope, this.stage is very much defined, and strict mode is on. It receives the events after I click on the swf. It's kind of like it looses focus, but it doesn't, because the deactivate event isn't triggered. My guess is something in my code is causing the focus to be set to something else, but I don't do this explicitely. Very strange.

I'm probably too drunnk to post atm, it's 4:27 am and I have to get up in a coupl'a hours. Hope I made at least some sense. Bananas are not people, but both can be eaten.

The blog is linked in my sig, and the entry is "Kentish town smokers", although there's not a lot more info in there about the issue to be honest, just general rants.
The blog contains the odd rude word, just a warning to younger members.

Squize.

Yeah already found it meanwhile, not much more info indeed.

I just noticed another prob, which should also occur with the senocular class you use (mine is very similar, but I wrote it before he posted his class way back when). When you right click, the deactivate event isn't called, so keys can still get stuck. I'm having trouble finding a on-contextmenu event, but it's probably in there somewhere. Any ideas would be appreciated.

Joy. I wasn't aware of that, thanks for flagging it up.

If I have any luck finding a work around I'll post back here.

Squize.

Thank you very much for this. :) I'm new to flash development, mixing and matching code and tips and whatnot from all over the place. I have something very similar to the Key class above and I was losing key events every time I switched out display objects.

putting "stage.focus=stage" in my switching code worked like a charm (so far, anyway ;) ). :)

I just ran into a similar issue yesterday, and would love to know if anyone has figured out what is going on?

Is this a bug that may not be in CS4 players?

i'm trying to put "stage.focus=stage" in various places to see if it will keep things going. I'm not sure i want it to be done every frame, but...

the description "seems to randomly stops receiving key events...have to click on the [interface] again so it receives events again, so it seems to have lost focus, but there is no reason for that." fits very very well...

It seems to only happen after I click on an item in the interface i'm building that then ends up getting swapped out with a different MovieClip, but at this point none of my MovieClips have any Key listeners in them, there is only one in the Main Class attached to the Stage....

i use stage.focus = this
on the game class that handles the key input stuff.

I have also run into problems though in the past where certain keyboards can only "hear" a certain number of key presses at the same time which might also be a problem....

The CASALib stuff has some nice stage management as well that Im starting to play with, though not much of an opinion on it yet.

Well, I had the same problem, so found this thread and the posts gave me the idea, it seems that when you click on any button, movieclip with mouse listener or input text fields, you lose focus in the stage which is the one listening for keyboard events, so, my solution was adding in every button function the line you gave before:

stage.focus=stage;

in my opinion it's not a player or code bug, it's the AS3 logic in which every element, even the stage is an object, so if you use another one, even being inside it, it loses focus, well, hope it helps, worked for me.

Quote:

---

Originally Posted by id_huevo

Well, I had the same problem, so found this thread and the posts gave me the idea, it seems that when you click on any button, movieclip with mouse listener or input text fields, you lose focus in the stage which is the one listening for keyboard events, so, my solution was adding in every button function the line you gave before:

stage.focus=stage;

in my opinion it's not a player or code bug, it's the AS3 logic in which every element, even the stage is an object, so if you use another one, even being inside it, it loses focus, well, hope it helps, worked for me.

---

Yep, I have had to do that to.

Do we have to add "stage.focus=stage;" on EVERY frame to turn around this bug ?

nope, just in the button functions, so, for example

myButton.addEventListener(MouseEvent.CLICK, stuffToDo);
function stuffToDo (event_object:MouseEvent):void{
// all of the button actions, and then:
stage.focus=stage;
}

that's it, just put this line in any button or function that forces to lose focus from the main stage and you are all set, keyboard listeners will keep working, good luck

Got the same problem, just find why. Focus on a object (sprite, mc, whatever) that you remove from stage and got garbage collect. Boom, loose stage focus.

Actually, didn't even required garbage collection, just child removal of a (sprite / mc / whatever) with focus kill stage focus.

So, with this new information (which seems consistent with the other posts) it seems like we could add the
stage.focus=stage;
wherever we use removeChild() as well.

Would it make sense to make a custom class called MySprite or something that inherits sprite and has a method myRemoveChild(args) that calls removeChild() along with the stage.focus=stage; line? Or would that just be silly?

Thanks -

Ran into the same problem. whatever.stage.focus = whatever.stage; worked great.

Quote:

---

Originally Posted by Fall_X

Yeah already found it meanwhile, not much more info indeed.

I just noticed another prob, which should also occur with the senocular class you use (mine is very similar, but I wrote it before he posted his class way back when). When you right click, the deactivate event isn't called, so keys can still get stuck. I'm having trouble finding a on-contextmenu event, but it's probably in there somewhere. Any ideas would be appreciated.

---

Maybe?

Code:

---


stage.addEventListener(MouseEvent.RIGHT_CLICK, clearKeys);

private static function clearKeys(event:MouseEvent):void {
    keysDown = new Object();
}

---

Should clear any keydef's the class is holding onto if you right click, but it's off the top of my head because I don't have time to test it.

Quote:

---

Originally Posted by fvidal

Got the same problem, just find why. Focus on a object (sprite, mc, whatever) that you remove from stage and got garbage collect. Boom, loose stage focus.

---

OMG, thank you very much.
This really helped me to fix my problem :).
Now after removeChild() I'm setting stage.focus = stage; and I know why it works which is important for me:)

I had this problem earlier today and found the best way around it was..

PHP Code:

---

//add a listener to check for focus loss
stage.addEventListener(FocusEvent.FOCUS_OUT, focusOut);

//reset focus when lost
public function focusOut(e:FocusEvent):void
{
    stage.focus = stage;
} 


---

Sorry for digging up this old thread, but I just ran into this issue, and I think there is another way to fix it, that might be better in most cases:

The flash component like a button or whatever seems to capture the event and stops its propagation. So it will never bubble up to the stage Object.

But don't forget: An event in Actionscript has 2 phases: the bubble phase, and the capture phase.
First, the event goes down from the stage to the element that is the target of the event. Then, it bubbles up again to the stage.
So just put your eventlistener in front into the capture phase, and you will be fine

Code:

---

this.stage.addEventListener(KeyboardEvent.KEY_DOWN, this.keyDown, true);

---

The true is the useCapture param.
Also, if your "this" might get removed from stage, it is good practice to make the event listener a weak reference, so the object can be collected by the garbagecollector:

Code:

---

this.stage.addEventListener(KeyboardEvent.KEY_DOWN, this.keyDown, true, 0, true);

---

im having the same problem, im gonna see if stage.focus=stage fixes it...

edit*** yup adding that before I call the creation of any other sprites in my enterframe function fixes all problems...