no default constructor found in base class ball

i want the class BeginBall to extend Ball, but when i do so, this error shows up.
this is my code:

PHP Code:

---

package
{
    import flash.events.Event;
    import flash.display.MovieClip;
    
    public class Ball extends MovieClip
    {
        public var nSpeedX:Number;
        public var nSpeedY:Number;
        public var ballNr:int;
        const BALLDIAMETER = 10;
        private var nStageWidth:Number = 500;
        private var nStageHeight:Number = 400;
        
        public function Ball ( X,Y,NSpeedX:Number, NSpeedY:Number ) : void
        {
            nSpeedX = NSpeedX;
            nSpeedY = NSpeedY;
            x = X;
            y = Y;
            
            this.addEventListener ( Event.ENTER_FRAME, onEnterFrameHandler );
        }
        
        private function onEnterFrameHandler ( E:Event ) : void
        {
            this.x -= nSpeedX;
            this.y -= nSpeedY;
            
            if ( this.x >= nStageWidth - BALLDIAMETER - 16 )
            {
                this.x = nStageWidth - BALLDIAMETER - 16;
                nSpeedX *= -1;
            }
            else if ( this.x <= BALLDIAMETER + 16 )
            {
                this.x = BALLDIAMETER + 16;
                nSpeedX *= -1;
            }
            
            if ( this.y >= nStageHeight - BALLDIAMETER - 16 )
            {
                this.y = nStageHeight - BALLDIAMETER - 16;
                nSpeedY *= -1;
            }
            else if ( this.y <= BALLDIAMETER + 16 )
            {
                this.y = BALLDIAMETER + 16;
                nSpeedY *= -1;
            }
            
        }
    }//end of class
    
    public class BeginBall extends Ball
    {
        //alles over spatieknop en muisknop etc.
    }
} 


---

i tried to do public last class Ball, butit says access identifiers are not allowed with namespace attributes.
how can i let BeginBall normally inherit Ball's constructor, or if its not possible, make a new one for BeginBall?

Try moving the helper class BeginBall outside of the package brackets.

doesn't work. same error.

How are you trying to instantiate it?

PHP Code:

---

var shootBall:ShootBall = new ShootBall;
            addChild(shootBall); 


---

changed the name in ShootBall btw, it's more suitable.

also try:

Constants

ActionScript 3.0 supports the const statement, which you can use to create constants. Constants are properties with a fixed value that cannot be altered. You can assign a value to a constant only once, and the assignment must occur in close proximity to the declaration of the constant. For example, if a constant is declared as a member of a class, you can assign a value to that constant only as part of the declaration or inside the class constructor.

The following code declares two constants. The first constant, MINIMUM, has a value assigned as part of the declaration statement. The second constant, MAXIMUM, has a value assigned in the constructor.

class A
{
public const MINIMUM:int = 0;
public const MAXIMUM:int;

public function A()
{
MAXIMUM = 10;
}
}

Well you define parameters for the constructor, but you are not passing any. a "default" constructor is one that takes no parameters, so what it is telling you is that it can not find the constructor defined in the way you are trying to use it.

ooh stupid me.
ps. i use constants. but u probably mean the 16 ? yeah i should change that into a constant.

edit: i now assigned the right variables in the instanciation, but the same problem exists, only this time it gives the same error twice. :/

I was actually referring to the fact that you did not explicitly declare an access modifier before it. Which I guess works and would default to internal I believe.

huh?? so what do i have to do?

Glancing at the code it looks like you have two classes in the same package. You should break them out into separate class files.

When you extend Ball, the constructor of the subclass must call super with the necessary arguments ( X,Y,NSpeedX:Number, NSpeedY:Number ) so that the Ball constructor for the subclass instance can be called correctly. Similarly, make sure you create your subclass instance with the right number of arguments... which is what I assume you fixed in your last post?

The problem is with your sub class. Since it extends Ball, it would have to construct ball when it is created and since it does not provide any parameters for the ball constructor, you get your error message.

LOL he beat me to it. Thanks Senocular.

i put it in a different as file in the same package, but it doesnt work. do i have to put it in another package? that would kinda annoy me. can't i do it someway different?

They don't have to be in different pacakges. Packages are just for organization.

You just need to make sure you call super() where needed and with the right arguments.

You may need to repost what code you're using now.

only the shootball instantiation changed:
var shootBall:ShootBall = new ShootBall(SHOOTBALLDOWN_X,SHOOTBALL_Y,0,0);
what is super()?

You haven't posted the ShootBall class.

super() is what lets you access superclass members, including the constructor. When you create a subclass of another class that is defined with required parameters in the constructor, your subclass is responsible for making sure those parameters are taken care of by passing arguments into those parameters of the superclass constructor. You call the superclass constructor through super.

So in your ShootBall constructor, you must call super using whatever values you see fit to define for ( X,Y,NSpeedX:Number, NSpeedY:Number )

Code:

---

public function ShootBall(){
    super(0,0, 10, 5);
}

---

this is what i have now, but it still doesnt work.(ignore everything under the constructor)

PHP Code:

---

package
{
    public class ShootBall extends Ball
    {
        private var touchable:Boolean = false;
        private var speedingLvl;
        alles over spatieknop en muisknop etc.
        public function ShootBall( X,Y,NSpeedX:Number, NSpeedY:Number)
        {
            super(X,Y,NSpeedX:Number, NSpeedY:Number)
        }
        
        function muisKnopKlik(event:Event)
        {
            //balkje begint te gaan
            speedingLvl = 0;
        }
        function muisKnopLos(event:Event)
        {
            mouseX - x
            mouseY - y
            
            
            
            function shootShootBall(hspeed,vspeed)
            {
                nSpeedX = hspeed;
                nSpeedY = vspeed;
                touchable = true;
            }
        }
        
    }
} 


---

asside from the misplaced "alles over spatieknop en muisknop etc." it seems passable.

Now, if you create an instance of ShootBall, you will need to be sure to pass in X,Y,NSpeedX:Number, NSpeedY:Number to that (not present in your previous code).

import ball class.

Quote:

---

Originally Posted by kortex

import ball class.

---

Unless you're using packages, that won't be necessary.

Yeah, but I have run into a couple of occasions where I had to do it anyway, so I thought I might suggest it.

the alles over.... should have been a comment.
but i did pass that all, and it still didnt work:

PHP Code:

---

var shootBall:ShootBall = new ShootBall(SHOOTBALLDOWN_X,SHOOTBALL_Y,0,0); 


---

and are you sure this is ok? it like kind of weird.

PHP Code:

---

public function ShootBall( X,Y,NSpeedX:Number, NSpeedY:Number)
        {
            super(X,Y,NSpeedX:Number, NSpeedY:Number)
        } 


---

super() is called just like any other function. You don't include the typing information. See my example above

but i want to put that information in the class instantiation
and it still doesnt work

What senocular is saying is that you do not need to put the typing information when you are calling the function (passing in values). That is done in the defining class.

i didnt...

@senocular Been playing with the classes without the import and low and behold, sure enough if they are in the same folder; no import statement needed. Was not aware of that, thanks.

it is in the code you posted:

Quote:

---

public function ShootBall( X,Y,NSpeedX:Number, NSpeedY:Number)
{
super(X,Y,NSpeedX:Number, NSpeedY:Number)
}

---

i changed it, still doesnt work.

Quote:

---

Originally Posted by omniscient232

i changed it, still doesnt work.

---

please give us an update of the code you're using; all of it

you can ignore most of it ofcourse:

class BallController:

PHP Code:

---

package
{
    import flash.display.MovieClip;
    import flash.display.Stage;
    import flash.events.Event;
    import flash.events.KeyboardEvent;
    
    public class BallController extends MovieClip
    {
        const BALLDIAMETER = 10;
        const SHOOTBALLUP_Y = BALLDIAMETER*0.5+16;
        const SHOOTBALLDOWN_Y = 600-(BALLDIAMETER*0.5+16);
        const SHOOTBALL_X = 200;
        
        private var mcBallContainer:MovieClip;
        private var nStageWidth:Number = 500;
        private var nStageHeight:Number = 400;
        public var numBalls:int;
        private var shootBallDown:Boolean = true;
        var shootBall:ShootBall;

        public function BallController() 
        {
            mcBallContainer = new MovieClip() ;
            mcBallContainer.x = mcBallContainer.y = 0;
            stage.addChild(mcBallContainer);
            
            this.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
            
            shootBall = new ShootBall(SHOOTBALL_X,SHOOTBALLDOWN_Y,0,0);
            addChild(shootBall);
            for ( var i = 0; i < 2; i++ )
            {
                createBall(Math.random() * nStageWidth,Math.random() * nStageHeight,Math.floor ( ( Math.random() * 12 ) - 4 ), Math.floor ( ( Math.random() * 12 ) - 4 ));
            }
        }
        
        private function enterFrameHandler(E:Event): void
        {
            for(var i = 0; i < mcBallContainer.numChildren; i++)
            {
                var mcBall1:* = mcBallContainer.getChildAt(i);
                
                for (var j = i + 1; j < mcBallContainer.numChildren; j++)
                {
                    var mcBall2:* = mcBallContainer.getChildAt(j);
                    
                    var nDistX:Number = Math.abs ( mcBall1.x - mcBall2.x );
                    var nDistY:Number = Math.abs ( mcBall1.y - mcBall2.y );
                    var nDistance:Number = Math.sqrt(nDistX * nDistX + nDistY * nDistY);
                    
                    if (nDistance < BALLDIAMETER*2)
                    {
                        solveBalls (mcBall1, mcBall2);
                    }
                }
            }
        }
        public function createBall(X,Y,speedX,speedY)
        {
            var mcBall:Ball = new Ball(X,Y,speedX,speedY);
            mcBall.ballNr = numBalls;
            mcBallContainer.addChild(mcBall);
            numBalls ++;
        }
        
        private function solveBalls (MCBallA:MovieClip, MCBallB:MovieClip):void
        {
            var nX1:Number = MCBallA.x;
            var nY1:Number = MCBallA.y;
            var nDistX:Number = MCBallB.x - nX1;
            var nDistY:Number = MCBallB.y - nY1;
            
            var nDistance:Number = Math.sqrt ( nDistX * nDistX + nDistY * nDistY );
            var nRadiusA:Number = MCBallA.width/2;
            var nRadiusB:Number = MCBallB.width/2;
            //var nRadius:Number = 10;
            
            var nNormalX:Number = nDistX/nDistance;
            var nNormalY:Number = nDistY/nDistance;
            
            var nMidpointX:Number = ( nX1 + MCBallB.x )/2;
            var nMidpointY:Number = ( nY1 + MCBallB.y )/2;
            
            MCBallA.x = nMidpointX - nNormalX * nRadiusA;
            MCBallA.y = nMidpointY - nNormalY * nRadiusA;
            MCBallB.x = nMidpointX + nNormalX * nRadiusB;
            MCBallB.y = nMidpointY + nNormalY * nRadiusB;
            
            var nVector:Number = ( ( MCBallA.nSpeedX - MCBallB.nSpeedX ) * nNormalX )+ ( ( MCBallA.nSpeedY - MCBallB.nSpeedY ) * nNormalY );
            var nVelX:Number = nVector * nNormalX;
            var nVelY:Number = nVector * nNormalY;
            
            MCBallA.nSpeedX -= nVelX;
            MCBallA.nSpeedY -= nVelY;
            MCBallB.nSpeedX += nVelX;
            MCBallB.nSpeedY += nVelY;
        }
        
        private function shootBallChange()
        {
            if (shootBall.touchable == false)
            {
                if (shootBallDown = true){
                    shootBallDown = false;
                    shootBall.y = SHOOTBALLDOWN_Y;
                }
                else
                {
                    shootBallDown = true;
                    shootBall.y = SHOOTBALLUP_Y;
                }
            }
        }
    }//end of class
}//end of package 


---

class Ball:

PHP Code:

---

package
{
    import flash.events.Event;
    import flash.display.MovieClip;
    
    public class Ball extends MovieClip
    {
        public var nSpeedX:Number;
        public var nSpeedY:Number;
        public var ballNr:int;
        const BALLDIAMETER = 10;
        private var nStageWidth:Number = 400;
        private var nStageHeight:Number = 600;

        
        public function Ball ( X,Y,NSpeedX:Number, NSpeedY:Number ) : void
        {
            nSpeedX = NSpeedX;
            nSpeedY = NSpeedY;
            x = X;
            y = Y;
            
            this.addEventListener ( Event.ENTER_FRAME, onEnterFrameHandler );
        }
        
        private function onEnterFrameHandler ( E:Event ) : void
        {
            this.x -= nSpeedX;
            this.y -= nSpeedY;
            
            if ( this.x >= nStageWidth - BALLDIAMETER - 16 )
            {
                this.x = nStageWidth - BALLDIAMETER - 16;
                nSpeedX *= -1;
            }
            else if ( this.x <= BALLDIAMETER + 16 )
            {
                this.x = BALLDIAMETER + 16;
                nSpeedX *= -1;
            }
            
            if ( this.y >= nStageHeight - BALLDIAMETER - 16 )
            {
                this.y = nStageHeight - BALLDIAMETER - 16;
                nSpeedY *= -1;
            }
            else if ( this.y <= BALLDIAMETER + 16 )
            {
                this.y = BALLDIAMETER + 16;
                nSpeedY *= -1;
            }
            
        }
    }//end of class
    
    
    /*public class PlayerBall extends Ball
    {
        
    }*/
} 


---

class ShootBall:

PHP Code:

---

package
{
    import flash.events.Event
    public class ShootBall extends Ball
    {
        public var touchable:Boolean = false;
        private var speedingLvl;
        private var barSpeed;
        //alles over spatieknop en muisknop etc.
        public function ShootBall( X,Y,NSpeedX:Number, NSpeedY:Number)
        {
            super(X,Y,NSpeedX, NSpeedY)
        }
        
        function muisKnopKlik(theEvent:Event):void
        {
            //balkje begint te gaan
            speedingLvl = 0;
        }
        function muisKnopLos(theEvent:Event):void
        {
            var dx:Number = parent.mouseX - x;
            var dy:Number = parent.mouseY - y;
            var angle:Number = Math.atan2(dy, dx);

            nSpeedX += Math.cos(angle)*barSpeed;
            nSpeedY += Math.sin(angle)*barSpeed;
            touchable = true;
        }
        
    }
} 


---

Are you getting errors?

ops. forgot to save :/ yeah this one works, after i removed the type definitions in the super() function.

thanks alot guys.

;)

:thumbsup: