i want to have an mc move left and right depending on where the user's mouse goes.

[fallrevenge]

Basically, I have a photo gallery, on a long horizontal strip. I want the user to navigate this strip by simply moving their mouse to the right to make it move right, and moving their mouse to the left to make it move left.

I know that there is a way to do this where you track the mouse whereever it is on the stage...but I'd only like it to be only active when it is over this particular strip.

Also, each thumbnail on this strip has a rollover effect. I would like to have that roll over effect stay active...

Any help would be appreciated.

Thanks.

[gparis]

Depending if the strip is a button or a movieclip, you'd use button or movieclip events to trigger the moving function, and yes you'll need to detect mouse position via _xmouse and _ymouse. Look at the Tween Class for more interesting movements if you're working with flash8.

gparis

[onine]

Check out the "Scrolling Thumbnail Panel" tutorial at:

http://gotoandlearn.com/download.php

You'll have to download the video tutorial (it's an .flv) and the .flv player he recommends.

It's worth it anyway. It's a good tute.

[cresquin]

I wrote a cool little script here that accomplishes the task.

http://board.flashkit.com/board/showthread.php?t=733185

[fallrevenge]

crequin, yes, but how do I make the strip actually move left and right, with easing?

[cresquin]

well, that's a bit different, and in fact a bit easier to accomplish. what you'll need to do is lay out your strip within a movieclip with your first menu item left top aligned to 0,0. Then you'll use the xmouse values proportionally to the width of your stage (or mask) to move your strip. Here's an example:

//myStrip is the menu with all the items in it
function onEnterFrame (){
    newX = (Stage.width / myStrip._width) * _xmouse;
    myStrip._x = newX; 
} 

to use an easing, you can use the tween class:

import mx.transitions.Tween;
import mx.transitions.easing.Regular;

var myTween:Tween = new Tween(myStrip, "_x", Regular.easeOut, myStrip._x, 0, 8, false);
function onEnterFrame (){
    var newX = (Stage.width / myStrip._width) * -_xmouse;
    myTween.continueTo(newX, 8);
} 

[fallrevenge]

that code is based on the stage width...what if I wanted it to be based on some MC that is less than the stage width.

So that it would be activated only when you are over that particular MC>

[cresquin]

my calculation of the newX values was sloppy before. To calculate the _x values properly, you need to move the strip a proportion of the difference between the strip total length and the stage width per _xmouse. Use this script instead.

import mx.transitions.Tween;
import mx.transitions.easing.Regular;

var myTween:Tween = new Tween(myStrip, "_x", Regular.easeOut, 0, 0, 8, false);
function onEnterFrame (){
    var newX = -_xmouse * ((myStrip._width - Stage.width) / Stage.width);
    myTween.continueTo(newX, 8);
} 

[cresquin]

to make it based on a MC, just change all the Stage.width calls to your limiting MC._width calls. you'll probably also want to add an if statement that checks to see if the mouse is within your limiting clip.

import mx.transitions.Tween;
import mx.transitions.easing.Regular;

var myTween:Tween = new Tween(myStrip, "_x", Regular.easeOut, 0, 0, 8, false);
function onEnterFrame (){
    if (_xmouse >= myLimit._x && _xmouse <=  myLimit._x + myLimit._width && _ymouse >= myLimit._y && _ymouse <=  myLimit._y + myLimit._height){
        var newX = -_xmouse * ((myStrip._width - myLimit._width) / myLimit._width);
        myTween.continueTo(newX, 8);
    }
} 

[fallrevenge]

that thing with the myLimit mc doesn't seem to work.

Like, let's say you want the active MC that limits it, to be half the size of the stage width.

Try it out in an fla....the strip mc flys off the screen, when you roll over the limit mc.

something is off.

???

[cresquin]

You're right, I dodged when I should have weaved. Try this.

import mx.transitions.Tween;
import mx.transitions.easing.Regular;

var myTween:Tween = new Tween(myStrip, "_x", Regular.easeOut, myLimit._x, myLimit._x, 8, false);
function onEnterFrame (){
    if (_xmouse >= myLimit._x && _xmouse <=  myLimit._x + myLimit._width && _ymouse >= myLimit._y && _ymouse <=  myLimit._y + myLimit._height){
        var dx = myStrip._width - myLimit._width;
        var xPosPercent = myLimit._xmouse / myLimit._width;
        
        var newX = myLimit._x - xPosPercent * dx;
        //myStrip._x = newX;
        myTween.continueTo(newX, 8);
    }
} 

[fallrevenge]

that works well. Sweet. Now, what if I wanted to use mc_tween, instead of the mx.transitions.

Mc_tween has a nice "easeOutExpo", that I think would work well.


THANKS

[cresquin]

I don't know mc_tween. perhaps it's possible... but simply changing Regular to Strong (in both places might just give you what you're looking for... try Elastic too, while you're at it